u-boot内存控制器初始化分析

u-boot内存控制器在第一阶段进行初始化：cpu_init_crit --> lowlevel_init
架构：ARM9u-boot版本：u-boot-1.1.6这里需要区分的是ldr指令和ldr伪指令。ldr指令是读取一个地址中的数据，相当于指针的解引用。ldr伪指令直接赋值，"="后面的值赋给"="前面的寄存器就对了。
还有就是汇编中的地址标号，保存的都是绝对地址（链接地址）。

/* 这段程序的作用就是用存在FLASH中的数据来配置内存控制器 */

_TEXT_BASE: /* 地址标号，相当于指针，这个地址是链接地址 */
.word TEXT_BASE /* 在单板目录的config.mk文件中定义 */

.globl lowlevel_init
lowlevel_init:
ldr r0, =SMRDATA /* 赋值伪指令 r0 = 0x33F8xxxx */
ldr r1, _TEXT_BASE /* 读内存指令 r1 = 0x33F80000 */
sub r0, r0, r1 /* r0 = SMRDATA标号在NOR FLASH中的地址 */
ldr r1, =BWSCON /* r1 = 内存控制器寄存器组的开始地址 */
add r2, r0, #13*4 /* r2 = 数据池的结束地址，下面的内存池正好13行 */
0:
ldr r3, [r0], #4 /* 读取数据池中的数据，r0指向下一个地址 */
str r3, [r1], #4 /* 用读取的数据存入配置内存控制器的寄存器 */
cmp r2, r0 /* 判断数据池是否读取完毕 */
bne 0b /* 没有读取完毕则跳到0标号继续读取 */

mov pc, lr

.ltorg /* 声明一个数据缓冲池 */

SMRDATA:
.word (0+(B1_BWSCON<<4)+(B2_BWSCON<<8)+(B3_BWSCON<<12)+(B4_BWSCON<<16)+(B5_BWSCON<<20)+(B6_BWSCON<<24)+(B7_BWSCON<<28))
.word ((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC))
.word ((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC))
.word ((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC))
.word ((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC))
.word ((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC))
.word ((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC))
.word ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN))
.word ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN))
.word ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Trc<<18)+(Tchr<<16)+REFCNT)
.word 0x32
.word 0x30
.word 0x30