Win32::EventLog - Process Win32 Event Logs from Perl

- NAME
- SYNOPSIS
- DESCRIPTION
- The EventLog Object and its Methods
- Other Win32::EventLog functions.
- Example 1
- Example 2
- BUGS
- AUTHOR

# NAME

Win32::EventLog - Process Win32 Event Logs from Perl

# SYNOPSIS

            use Win32::EventLog
            $handle=Win32::EventLog->new("Application");

# DESCRIPTION

This module implements most of the functionality available from the Win32 API for accessing and manipulating Win32 Event Logs. The access to the EventLog routines is divided into those that relate to an EventLog object and its associated methods and those that relate other EventLog tasks (like adding an EventLog record).

# The EventLog Object and its Methods

The following methods are available to open, read, close and backup EventLogs.

Win32::EventLog->new(SOURCENAME [,SERVERNAME]);
  The `new()` method creates a new EventLog object and returns a handle to it. This hande is then used to call the methods below.

  The method is overloaded in that if the supplied SOURCENAME argument contains one or more literal '\' characters (an illegal character in a SOURCENAME), it assumes that you are trying to open a backup eventlog and uses SOURCENAME as the backup eventlog to open. Note that when opening a backup eventlog, the SERVERNAME argument is ignored (as it is in the underlying Win32 API). For EventLogs on remote machines, the SOURCENAME parameter must therefore be specified as a UNC path.

$handle->Backup(FILENAME);
  The `Backup()` method backs up the EventLog represented by $handle. It takes a single arguemt, FILENAME. When $handle represents an EventLog on a remote machine, FILENAME is filename on the remote machine and cannot be a UNC path (i.e you must use C:\TEMP\App.EVT). The method will fail if the log file already exists.

$handle->Read(FLAGS, OFFSET, HASHREF);
  The `Read()` method read an EventLog entry from the EventLog represented by $handle.

$handle->Close();
  The `Close()` method closes the EventLog represented by $handle. After `Close()` has been called, any further attempt to use the EventLog represented by $handle will fail.

$handle->GetOldest(SCALARREF);
  The `GetOldest()` method number of the the oldest EventLog record in the EventLog represented by $handle. This is required to correctly compute the OFFSET required by the `Read()` method.

$handle->GetNumber(SCALARREF);
  The `GetNumber()` method returns the number of EventLog records in the EventLog represented by $handle. The number of the most recent record in the EventLog is therefore computed by

              $handle->GetOldest($oldest);
              $handle->GetNumber($lastRec);
              $lastRecOffset=$oldest+$lastRec;

$handle->Clear(FILENAME);
  The `Clear()` method clears the EventLog represented by $handle. If you provide a non-null FILENAME, the EventLog will be backed up into FILENAME before the EventLog is cleared. The method will fail if FILENAME is specified and the file refered to exists. Note also that FILENAME specifies a file local to the machine on which the EventLog resides and cannot be specified as a UNC name.

$handle->Report(HASHREF);
  The `Report()` method generates an EventLog entry. The HASHREF should contain the following keys:
  `Computer`
    The `Computer` field specfies which computer you want the EventLog entry recorded. If this key doesn't exist, the server name used to create the $handle is used.

  `Source`
    The `Source` field specifies the source that generated the EventLog entry. If this key doesn't exist, the source name used to create the $handle is used.

  `EventType`
    The `EventType` field should be one of the constants
    `EVENTLOG_ERROR_TYPE`
      An Error event is being logged.

    `EVENTLOG_WARNING_TYPE`
      A Warning event is being logged.

    `EVENTLOG_INFORMATION_TYPE`
      An Information event is being logged.

    `EVENTLOG_AUDIT_SUCCESS`
      A Success Audit event is being logged (typically in the Security EventLog).

    `EVENTLOG_AUDIT_FAILURE`
      A Failure Audit event is being logged (typically in the Security EventLog).

    These constants are exported into the main namespace by default.

  `Category`
    The `Category` field can have any value you want. It is specific to the particular Source.

  `EventID`
    The `EventID` field should contain the ID of the message that this event pertains too. This assumes that you have an associated message file (indirectly referenced by the field `Source`).

  `Data`
    The `Data` field contains raw data associated with this event.

  `Strings`
    The `Strings` field contains the single string that itself contains NUL terminated sub-strings. This are used with the EventID to generate the message as seen from (for example) the Event Viewer application.

# Other Win32::EventLog functions.

The following functions are part of the Win32::EventLog package but are not callable from an EventLog object.

GetMessageText(HASHREF);
  The `GetMessageText()` function assumes that HASHREF was obtained by a call to `$handle->Read()`. It returns the formatted string that represents the fully resolved text of the EventLog message (such as would be seen in the Windows NT Event Viewer). For convenience, the key 'Message' in the supplied HASHREF is also set to the return value of this function.

  If you set the variable $Win32::EventLog::GetMessageText to 1 then each call to `$handle->Read()` will call this function automatically.

# Example 1

The following example illustrates the way in which the EventLog module can be used. It opens the System EventLog and reads through it from oldest to newest records. For each record from the Source EventLog it extracts the full text of the Entry and prints the EventLog message text out.

     use Win32::EventLog;

     $handle=Win32::EventLog->new("System", $ENV{ComputerName})
            or die "Can't open Application EventLog\n";
     $handle->GetNumber($recs)
            or die "Can't get number of EventLog records\n";
     $handle->GetOldest($base)
            or die "Can't get number of oldest EventLog record\n";

     while ($x < $recs) {
            $handle->Read(EVENTLOG_FORWARDS_READ|EVENTLOG_SEEK_READ,
                                      $base+$x,
                                      $hashRef)
                    or die "Can't read EventLog entry #$x\n";
            if ($hashRef->{Source} eq "EventLog") {
                    Win32::EventLog::GetMessageText($hashRef);
                    print "Entry $x: $hashRef->{Message}\n";
            }
            $x++;
     }

# Example 2

To backup and clear the EventLogs on a remote machine, do the following :-

     use Win32::EventLog;

     $myServer="\\\\my-server";     # your servername here.
     my($date)=join("-", ((split(/\s+/, scalar(localtime)))[0,1,2,4]));
     my($dest);

     for my $eventLog ("Application", "System", "Security") {
            $handle=Win32::EventLog->new($eventLog, $myServer)
                    or die "Can't open Application EventLog on $myServer\n";

            $dest="C:\\BackupEventLogs\\$eventLog\\$date.evt";
            $handle->Backup($dest)
                    or warn "Could not backup and clear the $eventLog EventLog on $myServer ($^E)\n";

            $handle->Close;
     }

Note that only the Clear method is required. Note also that if the file $dest exists, the function will fail.

# BUGS

None currently known.

The test script for 'make test' should be re-written to use the EventLog object.

# AUTHOR

Original code by Jesse Dougherty for HiP Communications. Additional fixes and updates attributed to Martin Pauley <martin.pauley@ulsterbank.ltd.uk>) and Bret Giddings (bret@essex.ac.uk)

Win32::EventLog - Process Win32 Event Logs from Perl