constant - Perl pragma to declare constants

- NAME
- SYNOPSIS
- DESCRIPTION
- NOTES
- TECHNICAL NOTE
- BUGS
- AUTHOR
- COPYRIGHT

# NAME

constant - Perl pragma to declare constants

# SYNOPSIS

        use constant BUFFER_SIZE    => 4096;
        use constant ONE_YEAR       => 365.2425 * 24 * 60 * 60;
        use constant PI             => 4 * atan2 1, 1;
        use constant DEBUGGING      => 0;
        use constant ORACLE         => 'oracle@cs.indiana.edu';
        use constant USERNAME       => scalar getpwuid($<);
        use constant USERINFO       => getpwuid($<);

        sub deg2rad { PI * $_[0] / 180 }

        print "This line does nothing"              unless DEBUGGING;

        # references can be constants
        use constant CHASH          => { foo => 42 };
        use constant CARRAY         => [ 1,2,3,4 ];
        use constant CPSEUDOHASH    => [ { foo => 1}, 42 ];
        use constant CCODE          => sub { "bite $_[0]\n" };

        print CHASH->{foo};
        print CARRAY->[$i];
        print CPSEUDOHASH->{foo};
        print CCODE->("me");
        print CHASH->[10];                  # compile-time error

# DESCRIPTION

This will declare a symbol to be a constant with the given scalar or list value.

When you declare a constant such as `PI` using the method shown above, each machine your script runs upon can have as many digits of accuracy as it can use. Also, your program will be easier to read, more likely to be maintained (and maintained correctly), and far less likely to send a space probe to the wrong planet because nobody noticed the one equation in which you wrote `3.14195`.

# NOTES

The value or values are evaluated in a list context. You may override this with `scalar` as shown above.

These constants do not directly interpolate into double-quotish strings, although you may do so indirectly. (See the perlref manpage for details about how this works.)

        print "The value of PI is @{[ PI ]}.\n";

List constants are returned as lists, not as arrays.

        $homedir = USERINFO[7];             # WRONG
        $homedir = (USERINFO)[7];           # Right

The use of all caps for constant names is merely a convention, although it is recommended in order to make constants stand out and to help avoid collisions with other barewords, keywords, and subroutine names. Constant names must begin with a letter or underscore. Names beginning with a double underscore are reserved. Some poor choices for names will generate warnings, if warnings are enabled at compile time.

Constant symbols are package scoped (rather than block scoped, as `use strict` is). That is, you can refer to a constant from package Other as `Other::CONST`.

As with all `use` directives, defining a constant happens at compile time. Thus, it's probably not correct to put a constant declaration inside of a conditional statement (like `if ($foo) { use constant ... }`).

Omitting the value for a symbol gives it the value of `undef` in a scalar context or the empty list, `()`, in a list context. This isn't so nice as it may sound, though, because in this case you must either quote the symbol name, or use a big arrow, (`=>`), with nothing to point to. It is probably best to declare these explicitly.

        use constant UNICORNS       => ();
        use constant LOGFILE        => undef;

The result from evaluating a list constant in a scalar context is not documented, and is not guaranteed to be any particular value in the future. In particular, you should not rely upon it being the number of elements in the list, especially since it is not necessarily that value in the current implementation.

Magical values, tied values, and references can be made into constants at compile time, allowing for way cool stuff like this. (These error numbers aren't totally portable, alas.)

        use constant E2BIG => ($! = 7);
        print   E2BIG, "\n";        # something like "Arg list too long"
        print 0+E2BIG, "\n";        # "7"

Dereferencing constant references incorrectly (such as using an array subscript on a constant hash reference, or vice versa) will be trapped at compile time.

In the rare case in which you need to discover at run time whether a particular constant has been declared via this module, you may use this function to examine the hash `%constant::declared`. If the given constant name does not include a package name, the current package is used.

        sub declared ($) {
            use constant 1.01;              # don't omit this!
            my $name = shift;
            $name =~ s/^::/main::/;
            my $pkg = caller;
            my $full_name = $name =~ /::/ ? $name : "${pkg}::$name";
            $constant::declared{$full_name};
        }

# TECHNICAL NOTE

In the current implementation, scalar constants are actually inlinable subroutines. As of version 5.004 of Perl, the appropriate scalar constant is inserted directly in place of some subroutine calls, thereby saving the overhead of a subroutine call. See Constant Functions in the perlsub manpage for details about how and when this happens.

# BUGS

In the current version of Perl, list constants are not inlined and some symbols may be redefined without generating a warning.

It is not possible to have a subroutine or keyword with the same name as a constant in the same package. This is probably a Good Thing.

A constant with a name in the list `STDIN STDOUT STDERR ARGV ARGVOUT ENV INC SIG` is not allowed anywhere but in package `main::`, for technical reasons.

Even though a reference may be declared as a constant, the reference may point to data which may be changed, as this code shows.

        use constant CARRAY         => [ 1,2,3,4 ];
        print CARRAY->[1];
        CARRAY->[1] = " be changed";
        print CARRAY->[1];

Unlike constants in some languages, these cannot be overridden on the command line or via environment variables.

You can get into trouble if you use constants in a context which automatically quotes barewords (as is true for any subroutine call). For example, you can't say `$hash{CONSTANT}` because `CONSTANT` will be interpreted as a string. Use `$hash{CONSTANT()}` or `$hash{+CONSTANT}` to prevent the bareword quoting mechanism from kicking in. Similarly, since the `=>` operator quotes a bareword immediately to its left, you have to say `CONSTANT() => 'value'` (or simply use a comma in place of the big arrow) instead of `CONSTANT => 'value'`.

# AUTHOR

Tom Phoenix, <rootbeer@redcat.com>, with help from many other folks.

# COPYRIGHT

Copyright (C) 1997, 1999 Tom Phoenix

This module is free software; you can redistribute it or modify it under the same terms as Perl itself.

constant - Perl pragma to declare constants